学び直し九日目:2章 ブール算術⑤(2章完了)
記録
ALU の実装
昨日の考え方であっていた。"ALUの" コード自体は合っていた。だが、ハマった。。
// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl
/**
* The ALU (Arithmetic Logic Unit).
* Computes one of the following functions:
* x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
* x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs,
* according to 6 input bits denoted zx,nx,zy,ny,f,no.
* In addition, the ALU computes two 1-bit outputs:
* if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
* if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
*/
// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0 // 16-bit constant
// if (nx == 1) set x = !x // bitwise not
// if (zy == 1) set y = 0 // 16-bit constant
// if (ny == 1) set y = !y // bitwise not
// if (f == 1) set out = x + y // integer 2's complement addition
// if (f == 0) set out = x & y // bitwise and
// if (no == 1) set out = !out // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1
CHIP ALU {
IN
x[16], y[16], // 16-bit inputs
zx, // zero the x input?
nx, // negate the x input?
zy, // zero the y input?
ny, // negate the y input?
f, // compute out = x + y (if 1) or x & y (if 0)
no; // negate the out output?
OUT
out[16], // 16-bit output
zr, // 1 if (out == 0), 0 otherwise
ng; // 1 if (out < 0), 0 otherwise
PARTS:
// Put you code here:
// x の処理
Mux16(a=x, b=false, sel=zx, out=xx);
Not16(in=xx, out=notx);
Mux16(a=xx, b=notx, sel=nx, out=xxx);
// y の処理
Mux16(a=y, b=false, sel=zy, out=yy);
Not16(in=yy, out=noty);
Mux16(a=yy, b=noty, sel=ny, out=yyy);
// f = 0 の処理。And
And16(a=xxx, b=yyy, out=xandy);
// f = 1 の処理。Add
Add16(a=xxx, b=yyy, out=xaddy);
// f の値に合わせて mux
Mux16(a=xandy, b=xaddy, sel=f, out=fout);
// no の値に併せて mux
// zr 判定のための出力と、ng の判定出力も同時に行う
Not16(in=fout, out=notfout);
Mux16(a=fout, b=notfout, sel=no, out=out, out[0..7]=aout, out[8..15]=bout, out[15]=ng);
// zr の判定
Or8Way(in=aout, out=zr1);
Or8Way(in=bout, out=zr2);
Or(a=zr1, b=zr2, out=wzr);
Not(in=wzr, out=zr);
}
ハマった...
上記コードでいくらやっても、テストに通らなかった。1時間くらいうなって、ツールをダウンロードしなおしたけどダメだった。
よくよくツールの結果を調べてみると、Add16 の出力がおかしいことに気づいた。ので、以前自作したAdd16のコードを確認したところ、
CHIP FullAdder {
IN a, b, c; // 1-bit inputs
OUT sum, // Right bit of a + b + c
carry; // Left bit of a + b + c
PARTS:
// Put you code here:
HalfAdder(a=a, b=b, sum=s1, carry=c1);
HalfAdder(a=c, b=s1, sum=sum, carry=c2);
Or(a=c1, b=c2, out=carry);
// Or(a=c1, b=c2, out=out); // ここ間違えててハマった
}
となっていた。。。ひとつ下のレイヤをミスっていたので、その上のALUもバグってしまったらしい。
教訓
デバッグ時の引き出しがひとつ増えた。エラーを吐いたら、一段下の chip の HDL をプロジェクトフォルダから一時的に退避させて、ビルトインチップ使って通るか確認すべし。
で、どんどん低レイヤのチップに向けて問題箇所を絞り込んでいけばよさげ。
勉強になった。何歳になっても、失敗をして人は学ぶのである。
今日の筋トレ
今日は休筋日。